例を通して見ていくことにしよう。以下のコードに対して-ddump-dsすることを考える。

skip2 m = m : skip2 (m+2)

始める前に、名前について少々。GHC内部では、変数や型構築子などは「固有子(unique)」によって識別される。固有子は「文字」と「数値」(両方とも広く解釈する)をつなげた形をしている。「文字」部分はその固有子がどういう由来を持つのかを示す。例えば、_は「組込みの型変数」を意味し、tは「型検査器由来」、sは「単純化器由来」という具合である。「数値」部分は「base-62」形式でとてもコンパクトに表示されるが、私(WDP)以外の皆はこれが嫌いなようだ。

もう一度言うが、あらゆるものは「固有子」を持っていて、これは通常デバッグ時になんらかの形で出力される。ではいってみよう…

Desugared:
Main.skip2{-r1L6-} :: _forall_ a$_4 =>{{Num a$_4}} -> a$_4 -> [a$_4]

--# 「r1L6」はMain.skip2の固有子
--# 「_4」は型変数(テンプレート)「a」の固有子
--# 「{{Num a$_4}}」は辞書引数

_NI_

--# 「_NI_」は「まだ(実質的に)情報がない」を意味する。これは後に
--# GHC_PRAGMA情報になり、インタフェースファイルに行く。

Main.skip2{-r1L6-} =
    /\ _4 -> \ d.Num.t4Gt ->
        let {
          {- CoRec -}
          +.t4Hg :: _4 -> _4 -> _4
          _NI_
          +.t4Hg = (+{-r3JH-} _4) d.Num.t4Gt

          fromInt.t4GS :: Int{-2i-} -> _4
          _NI_
          fromInt.t4GS = (fromInt{-r3JX-} _4) d.Num.t4Gt

--# クラスメソッド「+」(固有子: r3JH)は辞書「Num」(今や明示的にラ
--# ムダで導入される引数である)から加算のコードを選択する。コアは
--# 二階のラムダ計算なので、型適用と型ラムダ(/\)は明示的である。
--# そのため、「+」は、まず型(「_4」)に適用され、次に辞書に適用さ
--# れている。この適用の結果が実際の加法関数であり、後で使われる。

--# (非標準の)クラスメソッド「fromInt」についても全く同じことを行
--# う。驚くに値しないが、型「Int」はコンパイラに結わえつけられて
--# いる。

          lit.t4Hb :: _4
          _NI_
          lit.t4Hb =
              let {
                ds.d4Qz :: Int{-2i-}
                _NI_
                ds.d4Qz = I#! 2#
              } in  fromInt.t4GS ds.d4Qz

--# 「I# 2#」というのは単なるリテラルのInt「2」のことである。これ
--# は、GHCが「data Int = I# Int#」と定義していることを反映してい
--# る。ここで、Int#はプリミティブの非ボックス化型である。(非ボッ
--# クス化型の関連情報についてはどこか別のところを見よ)

--# 「I#」の後の「!」は、データ構築子「I#」の適用が*飽和*している
--# (つまり、部分適用ではない)ことを示す。

          skip2.t3Ja :: _4 -> [_4]
          _NI_
          skip2.t3Ja =
              \ m.r1H4 ->
                  let { ds.d4QQ :: [_4]
                        _NI_
                        ds.d4QQ =
                    let {
                      ds.d4QY :: _4
                      _NI_
                      ds.d4QY = +.t4Hg m.r1H4 lit.t4Hb
                    } in  skip2.t3Ja ds.d4QY
                  } in
                  :! _4 m.r1H4 ds.d4QQ

          {- end CoRec -}
        } in  skip2.t3Ja

(「これは一つの単純な関数型言語に過ぎない」はPeyton Jones Enterprises, plc.の非レジスタ化商標です。)